source file: box.fts
\ 2009-02-05 ~mOleg
\ Copyright [C] 2009-2013 mOleg mOlegg@ya.ru
\ контейнеры с данными внутри кода

 ALSO HIDDEN ALSO FORTH DEFINITIONS

\ обойти данные в коде, начинающиеся со следующей ячейки,
\ вернуть адрес начала данных
\ : (BOX) ( r: addr --> addr ) AR@ CELL + AR@ @ R+ ;

\ для использования в других структурах не-immediate варианты BOX[ ]BOX
: BOX{ ( --> l: addr ) ?COMP COMPILE (BOX) HERE >L 0 , ;
: }BOX ( l: addr --> ) HERE L@ - L> ! ;

\ начать описание контейнера
: BOX[ ( --> l: addr ) BOX{ [COMPILE] [ ; IMMEDIATE

\ завершить описание контейнера, зафиксировать его размер,
\ вернуться к состоянию компиляции
: ]BOX ( l: addr --> ) }BOX ] ; IMMEDIATE

PREVIOUS RECENT

?ABSENT test{ \EOF -- тестовая секция ------------------------------------------

test{ : test 479875 BOX[ 49857 , -1984 , 564757 , ]BOX 98374 ;
      test 98374 <> THROW SWAP 479875 <> THROW
      DUP @ 49857 <> THROW
      DUP CELL + @ -1984 <> THROW
      2 CELLS + @ 564757 <> THROW
}test

\EOF пример использования:

: test ." контейнер данных в коде начинается с "
       BOX{ 10 ALLOT }BOX H.
       ." Адреса " ;

\EOF
так в пространстве слова можно хранить данные.
слова внутри скобок интерпретируются, а не компилируются !!!
пространство надо резервировать либо с помощью ALLOT, либо с помощью
компилирующих слов.

: samlpe   BOX{ 10 ALLOT }BOX ." адрес первого ящика: " . CR
               BOX{ 20 ALLOT }BOX ." адрес второго ящика: " . CR
               ;