вот надумалось: механизм, позволяющий избежать повторного подключения библиотек.
Код:
N?DEFINED libraryes \EOF
WARNING OFF
\ создаем словарь, в котором будут храниться имена подключенных
\ библиотек.
VOCABULARY libraryes
\ находится ли имя в списке подключенных библиотек?
: ?library ( asc # --> flag )
[ ALSO libraryes CONTEXT @ PREVIOUS ] LITERAL
SEARCH-WORDLIST IF DROP TRUE ELSE FALSE THEN ;
\ добавить имя в список подключенных либ
: +library ( asc # --> )
GET-CURRENT >R
ALSO libraryes THIS
SHEADER \ только заголовок
R> SET-CURRENT ;
\ попытка интерпретировать следующую лексему, как имя файла √
: NOTFOUND ( asc # --> )
STATE @ IF -1 THROW THEN
OVER C@ [CHAR] " =
IF <BACK ParseFileName THEN
2DUP ?library
IF 2DROP
ELSE 2DUP HEAP-COPY >R
['] INCLUDED CATCH
IFNOT R@ ASCIIZ> +library R> FREE DROP
ELSE R> FREE DROP THROW
THEN
THEN ;
WARNING ON
CURFILE @ ASCIIZ> NOTFOUND \ .\lib\add\libraryes.f
для удобного подключения библиотек (чтобы предварительно не искать все либы,
которые необходимо подключать перед используемой) удобно указывать в начале
библиотеки список необходимых библиотек. При этом, конечно, можно
пользоваться словом REQUIRE, но можно и предлагаемым механизмом. В отдельном
словаре libraryes сохраняем имена всех подключаемых библиотек, если имя
библиотечки в словаре найдено - по требованию библиотеку не подключаем, если
не найдено, соответственно подключаем.
Сразу видится одна проблема, связанная с тем, что один и тот же файл может
подключаться несколько раз в разные контексты, вопрос, на сколько этот
момент критичен.
Вторая проблема заключается в том, что "имя" одной и той же библиотеки может
быть записано различным образом: .\lib\name или lib\name возможны и другие
варианты 8(
В принципе, для удаления ненужных в сохраняемой наработке имен библиотек,
можно подключать данную библиотеку в HEAP , при этом придется заботиться,
чтобы HEAP был на вершине контекста(то есть выше словаря FORTH).
Вход
Регистрация
Благодарности
Forth-FAQ
